tunnel: upload aar to bintray

Signed-off-by: Jason A. Donenfeld <Jason@zx2c4.com>

build.gradle

@@ -27,10 +27,14 @@ buildscript {
         // gradle.properties.
         zxingEmbeddedVersion = '3.6.0'
         eddsaVersion = '0.3.0'
+        bintrayPluginVersion = '1.8.4'
+        mavenPluginVersion = '2.1'
     }
     dependencies {
         classpath "com.android.tools.build:gradle:$agpVersion"
         classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlinVersion"
+        classpath "com.github.dcendents:android-maven-gradle-plugin:$mavenPluginVersion"
+        classpath "com.jfrog.bintray.gradle:gradle-bintray-plugin:$bintrayPluginVersion"
     }
     repositories {
         google()

tunnel/build.gradle

@@ -29,3 +29,5 @@ dependencies {
     implementation "com.jakewharton.threetenabp:threetenabp:$threetenabpVersion"
     implementation "net.i2p.crypto:eddsa:$eddsaVersion"
 }
+
+apply from: "publish.gradle"

tunnel/publish.gradle

@@ -0,0 +1,65 @@
+apply plugin: 'com.github.dcendents.android-maven'
+apply plugin: 'com.jfrog.bintray'
+
+version wireguardVersionName
+group 'com.wireguard.android'
+
+install {
+    repositories.mavenInstaller {
+        pom.project {
+            name 'WireGuard Tunnel Library'
+            description 'Embeddable tunnel library for WireGuard for Android'
+            url 'https://www.wireguard.com/'
+
+            packaging 'aar'
+            groupId 'com.wireguard.android'
+            artifactId 'tunnel'
+            version wireguardVersionName
+
+            licenses {
+                license {
+                    name 'The Apache Software License, Version 2.0'
+                    url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
+                    distribution 'repo'
+                }
+            }
+            scm {
+                connection 'scm:git:https://git.zx2c4.com/wireguard-android'
+                url 'https://git.zx2c4.com/wireguard-android'
+            }
+            organization {
+                name 'WireGuard'
+                url 'https://www.wireguard.com/'
+            }
+        }
+    }
+}
+
+bintray {
+    user = hasProperty('BINTRAY_USER') ? getProperty('BINTRAY_USER') : System.getenv('BINTRAY_USER')
+    key = hasProperty('BINTRAY_KEY') ? getProperty('BINTRAY_KEY') : System.getenv('BINTRAY_KEY')
+
+    configurations = [ 'archives' ]
+
+    pkg {
+        repo = 'wireguard-android'
+        name = 'wireguard-android'
+        userOrg = 'wireguard'
+        licenses = [ 'Apache-2.0' ]
+        vcsUrl = 'https://git.zx2c4.com/wireguard-android'
+        publish = true
+
+        version {
+            name = wireguardVersionName
+        }
+    }
+}
+
+task sourcesJar(type: Jar) {
+    from android.sourceSets.main.java.srcDirs
+    archiveClassifier = 'sources'
+}
+
+artifacts {
+    archives sourcesJar
+}